Stdlib/std.log/Logger

Logger

struct Logger

Methods

pub fn new(writer: Write, max_level: Level = Level.Info, format: Format = Format.Default): Logger

[src]

pub fn new(writer: Write, max_level: Level = Level.Info, format: Format = Format.Default): Logger {
    return Logger {
        inner: _Logger
            .new(
                _create_native_write(writer),
                max_level: max_level._as_inner(),
                format: format as int
            ),
    };
}

Create a new logger that writes to the given output.

Options

max_level: The maximum log level to output. Defaults to Level.Info.
format: The log output format. Defaults to Format.Default.

Examples

nv,

use std.io;
use std.log.{Logger, Level};

let logger = Logger.new(io.stdout(), max_level: Level.Debug);
logger.info("Hello, world!");

pub fn prefix(self, prefix: string): Logger

[src]

pub fn prefix(self, prefix: string): Logger {
    return Logger { inner: self.inner, prefix_: prefix };
}

Create a new logger with the given tag.

This will prefix all log messages with the given tag.

nv,

use std.io;
use std.log.{Logger, Level};

let logger = Logger.new(io.stdout(), max_level: Level.Debug).prefix("myapp: ");
logger.info("Hello, world!");
// Output: "myapp: Hello, world!"

pub fn log(self, level: Level, args: ..ToString?)

[src]

fn log(self, level: Level, args: ..ToString?) {
    let msg_buf = StringBuffer.new();
    if (let prefix = self.prefix_) {
        msg_buf.push_string(prefix);
    }
    let first = true;
    for (let arg in args) {
        if (first) {
            first = false;
        } else {
            msg_buf.push_string(" ");
        }
        msg_buf.push_string(arg?.to_string() || "<nil>");
    }
    self.inner.log(level as int, msg_buf.to_string());
}

pub fn error(self, args: ..ToString?)

[src]

pub fn error(self, args: ..ToString?) {
    self.log(Level.Error, ..args);
}

Log a message at the error level.

pub fn warn(self, args: ..ToString?)

[src]

pub fn warn(self, args: ..ToString?) {
    self.log(Level.Warn, ..args);
}

Log a message at the warn level.

pub fn info(self, args: ..ToString?)

[src]

pub fn info(self, args: ..ToString?) {
    self.log(Level.Info, ..args);
}

Log a message at the info level.

pub fn debug(self, args: ..ToString?)

[src]

pub fn debug(self, args: ..ToString?) {
    self.log(Level.Debug, ..args);
}

Log a message at the debug level.

pub fn trace(self, args: ..ToString?)

[src]

pub fn trace(self, args: ..ToString?) {
    self.log(Level.Trace, ..args);
}

Log a message at the trace level.